[MarioRainer]

Hello,

one Question more...

I would like to insert a BLOCK. The block is selected in a Preview-Form.
I only find the function…

AvaxHandle = cAvax1.Add_Block(sBlockName, x1, y1, z1, vItemProperties, sScale, sAngle)

I would like to position the block with the mouse and not by code.

Can someone help me?

Thank you

Mario Rainer

[Athanasios Gardos]

Please, have a look at the following VB6 example:

Option Explicit

Private Sub cAvax1_SelectedPoints(SelectId As String, lPointNumber As Long, x1() As Single, y1() As Single, z1() As Single)
  Dim sBlockName As String, AvaxHandle As Long, sProp() As String
  Dim sScale As Single, sAngle As Single
  If SelectId = "Insert Block" Then
     If lPointNumber = 1 Then
        sBlockName = "test"
        sScale = 1
        sAngle = 0
        AvaxHandle = cAvax1.Add_Block(sBlockName, x1(1), y1(1), z1(1), sProp(), sScale, sAngle)
        If AvaxHandle = 0 Then
           MsgBox "Block " & sBlockName & " not found", vbCritical, ""
           cAvax1.Command = Redraw_c
        End If
     End If
  End If
End Sub

Private Sub Command1_Click()
  Dim sSelectID As String
  Dim lPointToSelect As Long
  Dim x() As Single, y() As Single, z() As Single
  sSelectID = "Insert Block"
  lPointToSelect = 1
  Call cAvax1.SelectPoints(sSelectID, lPointToSelect, x(), y(), z())
End Sub

Private Sub Form_Load()
  Command1.Caption = "Insert Block"
  Call cAvax1.StartAvax
End Sub

Private Sub Form_Unload(Cancel As Integer)
  Call cAvax1.EndAvax
End Sub

[MarioRainer]

Hello Sir,

thank you for the fast help, it´s great...

Mario Rainer